Adobe Flash Professional Version MX und höher
Adobe Flex
Die Technik bezieht sich auf:
Siehe User Agent Support for Flash für allgemeine Informationen zur Unterstützung durch Benutzeragenten.
Das Ziel dieser Technik ist es, eine längere, detailliertere Textinformation für ein Bild zur Verfügung zu stellen, als für den barrierefreien Namen des Bildes angemessen wäre. Neben dem Bild wird eine barrierefreie Schaltfläche bereitgestellt, die ein neues Bedienfeld anzeigt, das den langen Beschreibungstext des Bildes enthält.
In diesem Beispiel wird ein Bild, das statistische Daten enthält, gezeigt Das Bild hat eine kurze Textalternative ("Graph of percentage of total U.S. noninsitutionalized population age 16-64 declaring one or more disabilities"). Unter dem Bild kann der Benutzer auf eine Schaltfläche klicken, die in Textform eine lange Beschreibung der statistischen Informationen selber einblendet. Wenn die Schaltfläche angeklickt wird, dann werden die folgenden Schritte eingeleitet:
Der MovieClip, der die lange Beschreibung enthält, wird sichtbar gemacht und sein AccessibilityProperties.silent-Property wird auf falsch gesetzt, damit er für assistierende Techniken sichtbar wird. Seine Inhalte werden in der Tab-Reihenfolge platziert.
Das Originalbild und die Schaltfläche werden vorübergehend vor den assistierenden Techniken und der Tab-Reihenfolge versteckt.
Das Bild und der beschreibende Text stammen von HTML example for long image descriptions on WebAIM.org (HTML-Beispiel für lange Beschreibungen auf WebAIM.org)
Die Ergebnisse für diese Technik werden in der funktionierenden Version von Making a hidden description visible on request (Eine versteckte Beschreibung auf Anfrage sichtbar machen) gezeigt. Die Quelle für „Eine versteckte Beschreibung auf Anfrage sichtbar machen“ steht zur Verfügung.
Code-Beispiel:
import flash.accessibility. *;
import fl.accessibility.ButtonAccImpl;
import flash.system.Capabilities;
ButtonAccImpl.enableAccessibility();
//set accessibility properties
graph_mc.accessibilityProperties = new AccessibilityProperties();
graph_mc.accessibilityProperties.name = "Graph of percentage of total U.S. \
noninsitutionalized population age 16-64 declaring one or more disabilities";
longDescBtn.accessibilityProperties = new AccessibilityProperties();
longDesc_mc.accessibilityProperties = new AccessibilityProperties();
longDesc_mc.accessibilityProperties.forceSimple = false;
hideLongDesc();
//set click handlers for button
longDescBtn.addEventListener("click", function () {
showLongDesc()
});
longDesc_mc.longDescCloseBtn.addEventListener("click", function () {
hideLongDesc()
});
function showLongDesc() {
// hide the original content from screen readers
graph_mc.accessibilityProperties.silent = true;
graph_mc.tabEnabled = false;
graph_mc.alpha = 0.2;
longDescBtn.enabled = false;
longDescBtn.accessibilityProperties.silent = true;
longDesc_mc.accessibilityProperties.silent = false;
// make the long description panel visible, both visually and to screen readers
longDesc_mc.visible = true;
longDesc_mc.tabEnabled = true;
longDesc_mc.longDescTitle.stage.focus = longDesc_mc.longDescTitle;
if (Capabilities.hasAccessibility)
Accessibility.updateProperties();
}
function hideLongDesc() {
//do the opposite to what showLongDesc does
graph_mc.accessibilityProperties.silent = false;
graph_mc.tabEnabled = true;
graph_mc.alpha = 1;
longDescBtn.enabled = true;
longDescBtn.accessibilityProperties.silent = false;
longDesc_mc.visible = false;
longDesc_mc.accessibilityProperties.silent = true;
longDesc_mc.tabEnabled = false;
longDescBtn.stage.focus = longDescBtn;
if (Capabilities.hasAccessibility)
Accessibility.updateProperties();
}Wenn ein Flash-Film Bilder enthält, die lange Beschreibungen benötigen, dann bestätigen Sie, dass eine lange Beschreibung durch eine separate Schaltfläche bereitgestellt wird.
Das oben genannte ist wahr.
Wenn dies eine ausreichende Technik für ein Erfolgskriterium ist, dann bedeutet das Scheitern an diesem Testverfahren nicht zwangsläufig, dass das Erfolgskriterium nicht auf irgendeine andere Art und Weise erfüllt wurde, sondern nur, diese Technik nicht erfolgreich implementiert wurde und nicht benutzt werden kann, um die Konformität zu erklären.